An ASP Error Report Emailer

When you build websites for customers, it's often very difficult to find out the source of errors. Often the difficulties are mostly down to inaccurate error reports. For example, an error of "the page shows an error when I log in to the job search page" is a lot more difficult to fix than "the page shows a Microsoft VBScript runtime error number 500 (Variable is undefined) when I access job_search_login.asp".

A possible solution to the problem is to display friendly errors on the page. However, this looks unprofessional when the website users encounter them. A better solution is, therefore, to incorporate an error emailing script within your ASP pages. The SendErrorEmail function described on this page emails a comprehensive error report. A sample email error report is shown in the image on the left hand side of this page. The email includes details of what caused the error, together with the details of Application and Session objects, and the contents of the QueryString, Form and Server Variables collections.

Using the function

The SendErrorEmail function should be called from any ASP pages where errors are likely to occur. It is also useful to add the function to an include file that would allow the function to be used from all pages on a site. Further details of how to use include files is available on ASPAlliance.com.

Note that before the function is used, as little customisation is required. There are three areas of the script that need attention:

Once you have configured the script, it can be used using something like the following:

If Err.Number <> 0 Then
SendErrorEmail "ASP Error", Err.Source, Err.Number, Err.Description
End If

If you don't include this then your ASP page will stop processing when it encounters an ASP error and will not therefore send the email error report.

The SendErrorEmail function

The SendErrorEmail VBScript function below can be used to send an error email and report problems with an ASP page. Details of how to use the function are here. The function can also be viewed as a text file (easier for cutting and pasting).

<%
'Function to send an alert email
'Script from http://www.aspalliance.com/brettb/ErrorReportEmailer.asp
'Parameters used are:
' ErrorType = The type of error (e.g. "ASP Error")
' ErrorSource= Error source
' ErrorNumber = Error number
' ErrorDescription= Error description
'
'Changes required if you wish to use this script:
'
'1. Change the constant declarations so the email goes to you!
'
'2. If you disable session state then you must comment out the
' part of the script that extracts the details of the Session object
'
'3. If you want to use a mail sending object other than ASPMail you need to
' alter the mail sending part of the script
Function SendErrorEmail(ErrorType, ErrorSource, ErrorNumber, ErrorDescription)

 On Error Resume Next

 'Declare variables
 Dim HTML 'The HTML to send in the email
 Dim CollectionItem
 Dim iNumber
 Dim myMail 'Mail Server Component
 Dim QS
 Dim RF

 'Transfer the contents of the QueryString and Form collections to variables
 Set QS = Request.QueryString
 Set RF = Request.Form

 'Declare constants. YOU MUST CHANGE THESE WHEN USING THE SCRIPT ON YOUR OWN SITE
 Const MAIL_FROM_NAME = "MY WEBSERVER ERROR HANDLER" 'Name of email sender
 Const MAIL_FROM_EMAIL = "someone@someserver.com" 'Email address of email sender
 Const MAIL_TO_NAME = "MR. WEB DEVELOPER" 'Name of email recipient
 Const MAIL_TO_EMAIL = "someoneelse@someotherserver.com" 'Email address of email recipient
 Const MAIL_SUBJECT = "My Webserver Error Report" 'Title of error report
 Const MAIL_HOST = "smtp.someisp.com" 'Address of the host used to send the mail

 'Generate the top part of the error report
 HTML = "<!DOCTYPE HTML PUBLIC""-//IETF//DTD HTML//EN"">"
 HTML = HTML & "<html>"
 HTML = HTML & "<head>"
 HTML = HTML & "<title>" & MAIL_SUBJECT & "</title>"
 HTML = HTML & "</head>"
 HTML = HTML & "<body bgcolor=""FFFFFF"">"
 HTML = HTML & ""
 HTML = HTML & "" & MAIL_SUBJECT & " "
 HTML = HTML & "Error Report Generated: " & FormatDateTime(now(), vbLongDate) & ", " & FormatDateTime(now(), vbLongTime) & " "
 HTML = HTML & "<hr>"

 'Generate the error report general description
 HTML = HTML & "Details: "
 HTML = HTML & "Error In Page: " & Request.ServerVariables("PATH_INFO") & " "
 HTML = HTML & "Error Type: " & ErrorType & " "
 HTML = HTML & "Error Source: " & ErrorSource & " "
 HTML = HTML & "Error Number: " & ErrorNumber & " "
 HTML = HTML & "Error Description: " & ErrorDescription & " "
 HTML = HTML & "<hr>"

 'Report the contents of the QueryString collection
 HTML = HTML & "QueryString Collection: "
 If QS.Count > 0 Then
 For Each CollectionItem In QS
 HTML = HTML & CollectionItem & " : " & QS(CollectionItem) & " "
 Next
 Else
 HTML = HTML & "The QueryString collection is empty "
 End If

 HTML = HTML & "<hr>"

 'Report the contents of the Form collection
 HTML = HTML & "Form Collection: "

 If RF.Count > 0 Then
 For Each CollectionItem In RF
 HTML = HTML & CollectionItem & " : " & RF(CollectionItem) & " "
 Next
 Else
 HTML = HTML & "The Form collection is empty "
 End If

 HTML = HTML & "<hr>"

 'Report the Server object properties
 HTML = HTML & "Server Settings: "
 HTML = HTML & "ScriptTimeout: " & Server.ScriptTimeout & " "

 HTML = HTML & "<hr>"

 'Report the Session object properties and the contents of the Session collection
 'IMPORTANT: If you have disabled Sessions either in IIS or
 'by use of the @ENABLESESSIONSTATE = FALSE directive then you MUST comment out this section
 HTML = HTML & "Session Settings: "
 HTML = HTML & "CodePage: " & Session.CodePage & " "
 HTML = HTML & "LCID: " & Session.LCID & " "
 HTML = HTML & "SessionID: " & Session.SessionID & " "
 HTML = HTML & "Timeout: " & Session.TimeOut & " "

 HTML = HTML & "<hr>"

 HTML = HTML & "Session Collection: "

 For iNumber = 1 To Session.Contents.Count
 If IsObject(Session.Contents(iNumber)) Then
 HTML = HTML & Session.Contents.Key(iNumber) & "[Object] "
 Else
 If IsArray(Session.Contents(iNumber)) Then
 HTML = HTML & Session.Contents.Key(iNumber) & "[Array] "
 Else
 HTML = HTML & Session.Contents.Key(iNumber) & ": " & Session.Contents(iNumber) & " "
 End If
 End If
 Next

 HTML = HTML & "<hr>"

 'Report the contents of the Application collection
 HTML = HTML & "Application Collection: "

 For iNumber = 1 To Application.Contents.Count
 If IsObject(Application.Contents(iNumber)) Then
 HTML = HTML & Application.Contents.Key(iNumber) & "[Object] "
 Else
 If IsArray(Application.Contents(iNumber)) Then
 HTML = HTML & Application.contents.Key(iNumber) & "[Array] "
 Else
 HTML = HTML & Application.contents.Key(iNumber) & ": " & Application.Contents(iNumber) & " "
 End If
 End If
 Next

 HTML = HTML & "<hr>"

 'Report the contents of the Server Variables collection
 HTML = HTML & "Server Variables: "

 For Each CollectionItem in request.servervariables
 If CollectionItem <> "ALL_HTTP" and CollectionItem <> "ALL_RAW" then
 HTML = HTML & CollectionItem & " : " & request.servervariables(CollectionItem) & " "
 End If
 Next

 HTML = HTML & "</body>"
 HTML = HTML & "</html>"

 'Send the error report using email. This currently uses ASPMail from serverobjects.com, but could be
 'adapted to use another mail sending object (e.g. CDONTS) if required
 Set myMail = Server.CreateObject("SMTPsvg.Mailer")

 myMail.RemoteHost = MAIL_HOST
 myMail.FromName = MAIL_FROM_NAME
 myMail.FromAddress = MAIL_FROM_EMAIL

 myMail.AddRecipient MAIL_TO_NAME, MAIL_TO_EMAIL
 myMail.Subject = MAIL_SUBJECT
 myMail.BodyText = HTML
 myMail.ContentType = "text/html"

 If Not myMail.SendMail then

 SendErrorEmail = 0

 Else

 SendErrorEmail = 1

 End If

 Set myMail = Nothing

End Function
%>

Using CDONTS to send the error email

The script has been configured to use ASPMail from ServerObjects Inc.. It is of course possible to change the script so that it uses a different server component to send email. The code for using the CDONTS component that is usually installed on Windows NT Server is below:

'Send the error report using email. This currently uses CDONTS, but could be
 'adapted to use another mail sending object if required
 Set myMail = CreateObject("CDONTS.NewMail")

 With myMail
 .From = MAIL_FROM_NAME & "<" & MAIL_FROM_EMAIL & ">"
 .To = MAIL_TO_NAME & "<" & MAIL_TO_EMAIL & ">"
 .Subject = MAIL_SUBJECT
 .Value("MIME-Version") = "1.1"
 .BodyFormat=0
 .MailFormat=0
 .Body=HTML
 .Send
 End With

 Set myMail = Nothing

Summary

The function described on this page can be used to send a comprehensive report to help with diagnosing and solving ASP errors on a site. If you have any suggestions for further enhancements, then send me an email!

Code samples

Further reading

Useful Development Tools

ASP Documentation Tool™

Automatically creates technical documentation for ASP 2.0 and 3.0 web applications written in VBScript and JScript. Documentation for Microsoft Access, SQL Server 7/2000 databases and Visual Basic 6.0 components associated with the web application can also be incorporated into the reports. Documentation is created in HTML, HTML Help and plain text formats.

View Sample Output (HTML Help format).

View Sample Output (HTML Format).

Download Trial Version (5.2Mb ZIP file).

.NET Documentation Tool

Automatically creates technical documentation for .NET Framework applications written in C# or VB.NET (including ASP.NET). Documentation for SQL Server 7/2000/2005 databases and C#/VB.NET components associated with the web application can also be incorporated into the reports. Documentation is created in HTML, HTML Help and plain text formats. Additional support for ASP.NET web applications. A useful alternative to NDoc!

View Sample Output (HTML Help format).

View Sample Output (HTML Format).

Download Trial Version (3Mb ZIP file).

SQL Documentation Tool

The SQL Documentation Tool creates technical documentation for Microsoft SQL Server 7.0, 2000 and 2005 databases. Technical documentation is created in HTML and HTML Help formats. The HTML Help format documentation is fully searchable and cross referenced. The SQL Documentation Tool documents SQL Server Tables, Views, Stored Procedures, Triggers, Table Relationships, Jobs and DTS Packages.

View Sample Output (HTML Help format).

View Sample Output (HTML Format).

Download Trial Version (10.3Mb ZIP file).

VB Documentation Tool

The VB Documentation Tool creates technical documentation for Microsoft Visual Basic 6.0 projects. Technical documentation is created in HTML and HTML Help formats. The HTML Help format documentation is fully searchable and cross referenced.

View Sample Output (HTML Help format).

View Sample Output (HTML Format).

Download Trial Version (1Mb ZIP file).

The Website Utility

The Website Utility examines websites for errors and areas that need to be optimised for search engines by using a built in web crawling engine. Errors checked for include broken or moved hyperlinks, missing page titles and missing meta tags. It also generates HTML for use in creating website site maps (table of contents pages - like this one), and is able to create both client-side JavaScript search engines and server-side ASP search engines and ASP.NET search engines for a website.

View Sample Output (HTML Format).

Download Trial Version (3Mb ZIP file).

Text Workbench

Text Workbench is a file search and replacement utility for text files and Microsoft Office documents. Make rapid file replacements on multiple files and folders full of files. Advanced replacement options include regular expressions support. It even works on remote file systems via FTP. A Regular Expression Laboratory allows advanced pattern matching and replacement expressions to be built and tested. This great utility will make your everyday development tasks much easier!

Download Trial Version (3Mb ZIP file; you have the option to either install directly from this link or save the file for later installation).

Indexing Service Companion

The Indexing Service Companion is a utility that extends the functionality of the Microsoft Windows Indexing Service so that it is able to index content from any remote website and also from ODBC compliant databases. As such it can be used as a low cost alternative to Sharepoint's Search Services.

View Product Documentation (119K ZIP file).

Try Sample Search Facility.

Download Trial Version (1.7Mb ZIP file).

ASP Spell Check

ASPSpellCheck is the easy way to add spell checking capabilities to your ASP or ASP.NET websites, Intranets and web applications. The utility allows you to add spell checking capabilities to any HTML text field or rich content editing text box. It works with all common web browsers, and there are no components or databases to install on the server.

Read ASPSpellCheck Review.

View ASPSpellCheck Examples.

Download Trial Version (3Mb ZIP file; you have the option to either install directly from this link or save the file for later installation).

Author details

Brett Burridge has worked as a web developer since 1997 and has developed web applications for a range of corporations, start up busiensses and educational establishments.

Article history

"An ASP Error Report Emailer Function" published on ASPAlliance.com on 19 October 2001.